Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00112_DrawTools.ls

Text File | 2004-07-11 | 4.8 KB | 186 lines

--
-- Drawing tools class for the standard paint
--

-- this is tied to the score in the nystrom UI setup

property ancestor
property toolSprites
property currentTool
property canvasName
property canvasSprite

property startingPict  -- if startingPict exists, then we will replace the canvas with it on reset.



on new me
  -- initialize constants:
  -- default mode
  set currentTool = "freeHandLine"
  set toolSprites = []

  set ancestor = new (script "ScoreTools")

  set toolSprites = findColoredSprites(ancestor, 2, 1)

  if toolSprites = [] then
    alert "The tool sprites are not colored correctly in the score, they should be #2, green..."
    return 0
  end if

  -- put "tools: looking for the canvas..." & findColoredSprites(me, 1, 0)

  set canvasName = the name of member (the memberNum of sprite getAt(findColoredSprites(me, 1, 1), 1))
  set canvasSprite = sprite getAt(findColoredSprites(me, 1, 1), 1)

  return me
end


-- if this modification script is used, be sure that the bitmap cast member has a unique name!  There is currently no check for it.
-- also, the bitmap image must be 468 x 345

on initStartingPict me, bmpMemberName
  set startingPict = bmpMemberName
end



on getCurrentTool me
  return currentTool
end


-- handle the mousedowns right here
on mouseDownTools me, spr
  if toolSprites = [] then return 0

  if getPos(toolSprites, spr) > 0 then
    -- we hit a tool sprite

    -- each tool member must be named for a specific mode of the xtraDraw xtra
    set oldTool = currentTool

    --JCODE
    set theMemberNum = the memberNum of sprite spr
    set currentTool = item 1 of the name of member theMemberNum of castLib (the castlibNum of sprite spr)
    --END JCODE
    put "that tool is the: " & currentTool

    -- set the right cursor
    set topCurs = the number of member (string(currentTool & "Curs"))
    set mask = the number of member (string(currentTool & "Curs,mask"))
    set the cursor of sprite canvasSprite = [topCurs, mask]

    -- special case
    if currentTool = "reset" then
      bounceButton(me, "reset,down", spr)
      updateStage

      clearCanvas(me)
      set currentTool = oldTool
    end if

    case currentTool of

      "text":
        set the drawingMode of member canvasName = "text"

      "pencil":
        put "i am doing the pencil..."
        set the drawingMode of member canvasName = "freeHandLine"
        set the canvasPenSize of member canvasname = 1

      "brush":
        set the drawingMode of member canvasName = "freeHandLine"
        set the canvasPenSize of member canvasname = 2

      "fatBrush":
        set the drawingMode of member canvasName = "freeHandLine"
        set the canvasPenSize of member canvasname = 4

      "fill":
        set the drawingMode of member canvasName = "fill"

      "eraser":
        set the drawingMode of member canvasName = "freeHandLine"
        set the canvasPenSize of member canvasname = 16
        SetForeColor(member canvasName, 255, 255, 255)

      "circle":
        set the drawingMode of member canvasName = "framedCircle"
        set the canvasPenSize of member canvasname = 2

      "square":
        set the drawingMode of member canvasName = "framedSquare"
        set the canvasPenSize of member canvasname = 2

      "filledSquare":
        set the drawingMode of member canvasName = "filledSquare"
        --set the canvasPenSize of member canvasName =

      "filledCircle":
        set the drawingMode of member canvasName = "filledCircle"


    end case

    -- now we should do a bounce of the button, and turn off the other buttons
    radioToggle(me, toolSprites, spr, ",down")

    redraw(member canvasName)

    return 1
  else
    return 0
  end if
end


on clearCanvas me
  if voidP (startingPict) then
    -- if there is no staring pict then simply clear the canvas:
    set theOldMode = the drawingMode of member canvasName
    set the drawingMode of member canvasName = "fill"

    clear(member canvasName)
    redraw(member canvasName)
    set the drawingMode of member canvasName = theOldMode
  else
    -- if there is a startingpict then redraw it (written over the current canvas):
    set the drawingMode of member canvasName = "fill"
    SetImage (member canvasName, member startingPict, "fixed")
  end if
  return 1
end


on setCanvasSize me, h, w
  set the canvasHeight of member canvasName to h
  set the canvasWidth of member canvasName to w
end



on directOn me
  set the directToStage of member canvasName to TRUE
end


on directOff me
  set the directToStage of member canvasName to FALSE
end


on clearCanvasCursor me
  set the cursor of sprite canvasSprite = 0
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end